수식 관련 용어

• 함수: 입력값 집합에서 얻을 수 있는 출력값 집합의 관계로, 각 입력값은 하나의 출력값과 관계를 가집니다.

• 구문: 올바른 값을 반환하는 수식의 문자와 항의 순서를 나타냅니다.

• 인수: 함수의 모든 입력값을 나타냅니다(예: 속성).

• 문자열: 대부분 텍스트(즉, 나란히 있는 일련의 문자)를 나타냅니다. 수식에서 문자열은 항상 따옴표로 묶습니다.
• 하위 문자열은 특정 문자열의 한 부분입니다. 예를 들어, "No"는 "Notion"의 하위 문자열입니다.

• 부울: 부울은 true나 false의 값을 가지는 데이터 유형을 가리킵니다.

• 연결: 두 개의 문자열을 함께 결합합니다.
• 예: concat("추가", "텍스트")는 "추가텍스트"를 생성합니다.

용어 용례

• concat는 함수입니다. 함수는 특정 계산 또는 동작을 괄호 안의 입력값에 적용합니다.

• "추가"와 "텍스트"는 해당 함수의 인수입니다.

• 각 인수는 텍스트(문자열이라고도 함)입니다.

• 함수에는 체크박스(부울이라고도 함), 숫자 또는 날짜와 같은 다양한 인수를 사용할 수 있습니다.

• 함수 구문에서 문자열은 따옴표로 묶어야 하고 인수는 괄호 안에 넣어야 합니다.

수식 작성

• 먼저, 데이터베이스에서 새 속성을 추가하고 속성에 이름을 지정한 후, 속성 유형 메뉴에서 수식을 선택합니다.

• 수식이 특정 속성을 사용하여 작업을 수행할 수 있도록 함수를 입력합니다.

• 속성은 수식에서 변수와 같은 역할을 합니다. 함수를 입력할 때 속성명을 사용해 특정 속성을 가리킵니다.

• 디지털 계산기에 입력하듯이 함수를 입력하면 됩니다. 속성 입력 시 괄호와 따옴표로 묶는 것을 잊지 마세요!

• 예: 21세까지 남은 연수는?
• 데이터베이스에 나이 숫자 속성이 있고 21세가 될 때까지 몇 년이 남았는지를 계산하는 수식 속성이 필요하다고 가정해 봅니다.
• 21에서 데이터베이스에 포함된 사용자의 나이 속성 값을 뺀 결과를 반환하도록 21 - prop("나이")를 입력합니다.

수식 메뉴

• 속성: 데이터베이스에 사용되는 모든 속성을 나열합니다. 나열된 속성 중 하나를 클릭하면 해당 속성이 올바른 형식으로 수식에 삽입됩니다.

• 상수: 파이(π)와 같이 자주 쓰이는 상수입니다. 수식에 상수를 추가하려면 해당 상수를 클릭합니다.

• 연산자: 간단한 계산을 실행합니다. 연산자 왼쪽의 아이콘에는 연산자가 연산을 수행하는 유형이 표시됩니다. 예를 들어, 뺄셈과 덧셈은 숫자 속성에 대해 연산을 수행합니다.

• 함수: Notion에서 실행할 수 있는 복합적이며 미리 정의된 수식입니다. 함수 왼쪽의 아이콘은 함수가 연산을 수행하는 속성의 유형을 나타냅니다.

• 먼저, 창 상단에 있는 텍스트 상자에 원하는 함수를 입력하여 필요한 항목을 검색합니다.

• 화살표 키를 사용하여 위아래로 스크롤할 수도 있습니다.

• 예: 마감일까지 남은 일수
• 마감일이 있는 작업 데이터베이스가 있다고 가정해 봅시다. 목표는 지금부터 여러 개의 마감일까지 남은 일수를 파악하는 것입니다.
• 데이터베이스의 모든 작업마다 날짜 속성에 마감일을 입력합니다.
• 그런 다음, 새 속성을 추가하고 속성 유형 메뉴에서 수식을 선택합니다. 해당 이름으로 "남은 일수"를 지정합니다.
• 표의 수식 열에서 아무 셀이나 클릭하면 수식 창이 나타납니다.
 

• 제공된 텍스트 상자에 날짜를 입력하면 날짜 관련 명령이 표시됩니다. 원하는 시간 단위로 두 날짜 사이의 기간을 반환하는 dateBetween()을 사용하는 것이 적합합니다.

• 해당 함수의 지침에 따르면, 사용자는 두 날짜와 텍스트를 입력해야 합니다. 즉, 마감일, 현재 날짜, 두 날짜 사이의 기간을 나타낼 단위(년, 월, 일 등)를 지정해야 합니다.

• 수식 사이드바 상단에 있는 속성 아래에서 dateBetween() 함수를 클릭하거나 prop("마감일")을 입력하여 함수에 마감일을 삽입합니다.

• 그러면 수식이 dateBetween(prop("마감일"))로 변하게 됩니다. 오늘 날짜를 입력하는 함수로는 현재 날짜를 반환하는 now()를 사용하겠습니다.

• 이 함수를 완성하는 방법은 다음과 같습니다.
• 먼저, 쉼표를 추가하여 함수가 마감일과 현재 날짜 사이의 시간을 구하도록 지시합니다(dateBetween(prop("마감일"), now())).
• 그런 다음, 결과를 표시할 시간 단위를 정의합니다(dateBetween(prop("마감일"), now(), "days")).
• 마지막으로, 완료를 클릭하여 함수를 데이터베이스에 적용합니다.
• 다 끝났습니다! 이제 마감일까지 며칠이 남았는지 알 수 있습니다 🙌

일반적인 예시

자동 체크박스

• 목표: 우선순위에 입력값이 없거나 "중요"라는 단어를 포함하는 경우 체크박스를 체크합니다.
• 수식: or(empty(prop("우선순위")), prop("우선순위") == "중요")

• equal(prop("선택"), "옵션 1")

날짜 계산

• 목표: 더글라스(Douglas)가 지금까지 근무한 연수를 "근무 연수" 아래에 표시합니다.
• 수식: dateBetween(now(), prop("시작일"), "years")

• 목표: 더글라스(Douglas)에게 남은 근무 기간을 "남은 근무 기간" 아래에 표시합니다.
• 수식: dateBetween(prop("종료일"), now(), "years")
 

• 목표: 더글라스(Douglas)가 지금까지 근무한 기간을 연수로, 남은 기간을 개월 수로 "포맷 적용 텍스트" 아래에 표시합니다.
• 수식: concat(format(prop("근무 연수")), " 년, ", format(dateBetween(prop("종료일"), now(), "months")), " 월")
 

반올림 수식

• 정수로 반올림: 수식을 round()로 묶습니다.
• 예: round(prop("하나") / prop("둘"))

• 소수점 이하 한 자리로 반올림: 수식을 round(*10)/10로 묶습니다.
• 예: round(prop("하나") / prop("둘") * 10) / 10

• 소수점 이하 두 자리로 반올림: 수식을 round(*100)/100로 묶습니다.
• 예: round(prop("하나") / prop("둘") * 100) / 100

날짜에 요일 추가

• formatDate(prop("날짜"), "dddd, MMMM D, YYYY")

기한 지남 알림

• prop("마감일") < now()

문제 해결

• Type mismatch: prop("숫자") is not a Text
• 이 메시지는 사용하려는 수식에 텍스트 속성만 사용할 수 있다는 것을 의미합니다.
• 해결 방법은 숫자 속성을 format()으로 묶는 것입니다.
• 예: prop("숫자") + prop("텍스트")는 오류를 반환합니다. 이 수식을 format(prop("숫자")) + prop("텍스트")로 변경합니다.

• Too few arguments in function if
• 이 오류는 "else" 문이 누락되었을 수 있음을 의미합니다.
• 수식 맨 끝에 , "")를 추가하여 "else empty"를 추가해 봅니다.
• 예: if(prop("1") == "이것", "저것")은 오류를 반환합니다.
이 수식을 if(prop("1") == "이것", "저것", "")로 변경합니다.

자주 묻는 질문(FAQ)

관련 가이드